Comment please note that all calculation are based on the paper pencil SVO Slider measure, version A

COMMENT Calculation of SVO Angle (based on SVO items 01-06)

COMPUTE SVO_mean_first_six_Items_Self=MEAN(SVO_Item_01_Self,SVO_Item_02_Self,SVO_Item_03_Self,
    SVO_Item_04_Self,SVO_Item_05_Self,SVO_Item_06_Self).

COMPUTE SVO_mean_first_six_Items_Other=MEAN(SVO_Item_01_Other,SVO_Item_02_Other,SVO_Item_03_Other,
    SVO_Item_04_Other,SVO_Item_05_Other,SVO_Item_06_Other).

COMPUTE SVO_angle=(ARTAN(((SVO_mean_first_six_Items_Other-50)/(SVO_mean_first_six_Items_Self-50)))*180)/3.14159265359.
EXECUTE.


COMMENT Recoding of the SVO angle into 4 types

RECODE SVO_angle (Lowest thru -12.03=1) (-12.04 thru 22.44=2) (22.45 thru 57.15=3) (57.16 thru 
    Highest=4) INTO SVO_type.
EXECUTE.

VALUE LABELS SVO_type
1 'competitive'
2 'individualistic'
3 'prosocial'
4 'altruistic'.
EXECUTE.

COMMENT Calculation of the Inequality aversion (IA) index, which indicates whether the behavior of a prosocial subject is mainly driven by inequality aversion or joint gain maximization (based on SVO Items 07-15)
 
COMPUTE DIA=( ABS((SVO_Item_07-6)) / 8 + ABS((SVO_Item_08-5)) / 8  + ABS((SVO_Item_09-4)) / 8 + 
    ABS((SVO_Item_10-7)) / 8 + ABS((SVO_Item_11-5)) / 8 + ABS((SVO_Item_12-8)) / 8 + 
    ABS((SVO_Item_13-5)) / 8 + ABS((SVO_Item_14-3)) / 8 + ABS((SVO_Item_15-2)) / 8) / 9 .

COMPUTE DJG=( ABS((SVO_Item_07-9)) / 8 + ABS((SVO_Item_09-1)) / 8 + 
    ABS((SVO_Item_10-9)) / 8 + ABS((SVO_Item_12-9)) / 8 + 
    ABS((SVO_Item_14-1)) / 8 + ABS((SVO_Item_15-1)) / 8) / 6 .

COMPUTE DAL=( ABS((SVO_Item_07-9)) / 8 + ABS((SVO_Item_08-1)) / 8  + ABS((SVO_Item_09-9)) / 8 + 
    ABS((SVO_Item_10-9)) / 8 + ABS((SVO_Item_11-1)) / 8 + ABS((SVO_Item_12-1)) / 8 + 
    ABS((SVO_Item_13-1)) / 8 + ABS((SVO_Item_14-9)) / 8 + ABS((SVO_Item_15-1)) / 8) / 9 .

COMPUTE DIC=( ABS((SVO_Item_07-1)) / 8 + ABS((SVO_Item_08-9)) / 8  + ABS((SVO_Item_09-1)) / 8 + 
    ABS((SVO_Item_10-1)) / 8 + ABS((SVO_Item_11-9)) / 8 + ABS((SVO_Item_12-9)) / 8 + 
    ABS((SVO_Item_13-9)) / 8 + ABS((SVO_Item_14-1)) / 8 + ABS((SVO_Item_15-9)) / 8) / 9 .

VARIABLE LABELS DIA 'Difference to inequality averse type' DJG 'Difference to joint gain type' DAL 'Difference to altruistic type' DIC 'Difference to individualistic type'.


COMMENT IA_Index is only calulated if the following conditions are satisfied: Subject must be a prosocial type and the difference to the DIA type and DJG type must be smaller than the difference to the two other types (DAL, DIC)

IF  (DIA  <=  DIC  &  DIA  <= DAL  & DJG  <= DIC  &  DJG  <= DAL  & SVO_type = 3) IA_Index=DIA / 
    (DIA + DJG).

VARIABLE LABELS IA_Index 'Inequality Aversion Index'.

VALUE LABELS IA_Index
0 'perfect IA Type'
1 'perfect JG Type'.

EXECUTE.